/**
* TimeGraph
* A graph of something that changes over time
* @author Zeh
* @version 1.0
*/

package com.zehfernando.display.debug {
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Sprite;
	import flash.geom.Point;
	import flash.geom.Rectangle;	

	public class TimeGraph extends Sprite {

		// Constants
		private static const BACKGROUND_COLOR:int = 0x000000;
		private static const FOREGROUND_TOP_COLOR:int = 0xff0000;
		private static const FOREGROUND_COLOR:int = 0x770000;
		private static const FOREGROUND_INTERVAL_COLOR:int = 0xbb1111;

		// Private properties
		private var graphWidth:uint;
		private var graphHeight:uint;
		private var bitmapData:BitmapData;
		private var bitmap:Bitmap;
		
		public function TimeGraph(p_width:uint = 100, p_height:uint = 100) {

			graphWidth = p_width;
			graphHeight = p_height;
			
			// Create Bitmap
			bitmapData = new BitmapData(graphWidth, graphHeight, false, BACKGROUND_COLOR);
			bitmap = new Bitmap(bitmapData);
			addChild(bitmap);
		}

		public function push(p_value:Number, isInterval:Boolean = false): void {
			// Adds a new value to the graph (0-1)
			p_value = p_value < 0 ? 0 : p_value > 1 ? 1 : p_value;

			// Shifts existing content to the left
			bitmapData.copyPixels(bitmapData, new Rectangle(1, 0, graphWidth-1, graphHeight), new Point(0, 0));
			
			// Draws new bar
			var barX:uint = graphWidth - 1;
			var barHeight:uint = Math.round(p_value * graphHeight);
			var barY:uint = graphHeight - barHeight;
			bitmapData.fillRect(new Rectangle(barX, 0, 1, graphHeight), BACKGROUND_COLOR);
			bitmapData.fillRect(new Rectangle(barX, barY+1, 1, barHeight-1), isInterval ? FOREGROUND_INTERVAL_COLOR : FOREGROUND_COLOR);
			bitmapData.fillRect(new Rectangle(barX, barY, 1, 1), FOREGROUND_TOP_COLOR);
		}
	}
	
}