package com.zehfernando.display.components {
	import flash.display.Sprite;
	import flash.geom.Rectangle;
	import flash.text.AntiAliasType;
	import flash.text.StyleSheet;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFormat;
	import flash.text.TextFormatAlign;
	import flash.text.TextLineMetrics;

	/**
	 * @author Zeh
	 */
	public class TextFieldSprite extends Sprite {

		// Properties
		protected var _blockAlignVertical:String;
		protected var _blockAlignHorizontal:String;
		
		protected var _width:Number;
		protected var _height:Number;
		protected var _autoSize:Boolean;

		// Instances
		protected var textField:TextField;

		// ================================================================================================================
		// CONSTRUCTOR ----------------------------------------------------------------------------------------------------

		public function TextFieldSprite(__font:String = "_sans", __size:Number = 12, __color:Number = 0x000000, __bold:Boolean = false) {
			// Set default values
			_blockAlignVertical = TextSpriteAlign.MIDDLE;
			_blockAlignHorizontal = TextSpriteAlign.CENTER;
			
			_width = 0;
			_height = 0;
			
			// Create assets
			var fmt:TextFormat = new TextFormat(__font, __size, __color, __bold);
			fmt.align = TextFormatAlign.LEFT;
			
			textField = new TextField();
			//textField.scaleX = numberTextField.scaleY = 10;
			textField.selectable = false;
			textField.embedFonts = true;
			textField.autoSize = TextFieldAutoSize.LEFT;
			textField.antiAliasType = AntiAliasType.ADVANCED;
			textField.defaultTextFormat = fmt;
			textField.setTextFormat(fmt);
			textField.text = "";
			addChild(textField);
			
			autoSize = true;
			
			//resetTextPosition();
		}

		// ================================================================================================================
		// INTERNAL functions ---------------------------------------------------------------------------------------------

		protected function resetTextPosition(): void {
			// Sets the position of the text based on the current alignment
			
			var actualBoundaries:Rectangle = new Rectangle(0, 0, 0, 0);
			var descentOffset:Number = 0;

			// Read all metrics about the text position
			if (textField.text.length > 0) {
				var ty:Number, tx:Number, tw:Number, th:Number;
				var tmpP:Number;
				var mts:TextLineMetrics;
				
				th = 0;
				
				// Accounts for variable X - not sure if this ever happens, test with right/center alignment
				for (var i:int = 0; i < textField.numLines; i++) {
					mts = textField.getLineMetrics(i);
					
					// Left
					tmpP = mts.x;
					if (isNaN(tx) || tmpP < tx) tx = tmpP;
	
					// Width
					tmpP = mts.width + mts.x;
					if (isNaN(tw) || tmpP > tw) tw = tmpP;
					
					// Height
					th += mts.height;
				}

				// Descent
				descentOffset = textField.getLineMetrics(textField.numLines - 1).descent;
				
				var firstChar:Rectangle = textField.getCharBoundaries(0);
				if (Boolean(firstChar)) {
					ty = firstChar.y;
				} else {
					ty = 0;
				}
				
				th = textField.textHeight; // UGH // TODO: fix this?
				
				actualBoundaries.x = tx;
				actualBoundaries.y = ty;
				actualBoundaries.width = tw - tx;
				actualBoundaries.height = th;
			}

			// Finally, set all positions

			// Fix vertical position
			if (_blockAlignVertical == TextSpriteAlign.TOP) {
				// Top
				textField.y = -actualBoundaries.y;
			} else if (_blockAlignVertical == TextSpriteAlign.BOTTOM) {
				// Bottom
				textField.y = -actualBoundaries.y - actualBoundaries.height;
			} else if (_blockAlignVertical == TextSpriteAlign.BASELINE) {
				// Baseline bottom
				textField.y = -actualBoundaries.y - actualBoundaries.height + descentOffset;
			} else {
				// Middle
				textField.y = -actualBoundaries.y - actualBoundaries.height/2;
			}

			// Fix horizontal position
			if (_blockAlignHorizontal == TextSpriteAlign.LEFT) {
				// Left
				textField.x = -actualBoundaries.x;
			} else if (_blockAlignHorizontal == TextSpriteAlign.RIGHT) {
				// Right
				textField.x = -actualBoundaries.x - actualBoundaries.width;
			} else {
				// Center
				textField.x = -actualBoundaries.x - actualBoundaries.width/2;
			}
			
			_width = actualBoundaries.width;
			_height = actualBoundaries.height;
			
			//if (_height != textField.textHeight && !_autoSize && textField.textHeight > textField.height) {
				// Temporary workaround for when a textfield with auto size fails to take the actual height of the text 
				//textField.height = _height + 20;
				//trace ("RESET!");
			//}
			
			//trace ("h = " + _height + ",  tf.h = " + textField.height + ", tf.th = " + textField.textHeight);
		}
		
		protected function redrawWidth(): void {
			// Set the desired width of the textfield
			var widthOffset:Number = textField.width - textField.textWidth;
			textField.width = _width + widthOffset;
			resetTextPosition();
		}
		
		protected function setTextFormatProperties(__props:Object): void {
			// Set properties of the textfield's text format 
			// TODO: set selectively, so it won't overwrite anything?
			var fmt:TextFormat = textField.getTextFormat();
			for (var i:String in __props) {
				fmt[i] = __props[i];
			}
			textField.defaultTextFormat = fmt;
			textField.setTextFormat(fmt);
			resetTextPosition();
		}

		// ================================================================================================================
		// PUBLIC functions -----------------------------------------------------------------------------------------------

		// Textfield extensions
		public function getTextFormat(beginIndex:int = -1, endIndex:int = -1): TextFormat {
			return textField.getTextFormat(beginIndex, endIndex);
		}

		public function setTextFormat(format:TextFormat, beginIndex:int = -1, endIndex:int = -1): void {
			textField.setTextFormat(format, beginIndex, endIndex);
		}

		// ================================================================================================================
		// ACCESSOR functions ---------------------------------------------------------------------------------------------

		public function get blockAlignVertical(): String {
			return _blockAlignVertical;
		}
		public function set blockAlignVertical(__value:String): void {
			if (_blockAlignVertical != __value) {
				_blockAlignVertical = __value;
				resetTextPosition();
			}
		}

		public function get blockAlignHorizontal(): String {
			return _blockAlignHorizontal;
		}
		public function set blockAlignHorizontal(__value:String): void {
			if (_blockAlignHorizontal != __value) {
				_blockAlignHorizontal = __value;
				resetTextPosition();
			}
		}

		public function get autoSize(): Boolean {
			return _autoSize;
		}
		public function set autoSize(__value:Boolean): void {
			if (_autoSize != __value) {
				_autoSize = __value;
				//textField.autoSize = _autoSize ? TextFieldAutoSize.LEFT : TextFieldAutoSize.NONE;
				//textField.autoSize = _autoSize ? TextFieldAutoSize.LEFT : TextFieldAutoSize.LEFT;
				resetTextPosition();
			}
		}

		override public function get width(): Number {
			return _width;
		}
		override public function set width(__value:Number): void {
			if (_width != __value) {
				_width = __value;
				autoSize = false;
				redrawWidth();
			}
		}
		
		override public function get height(): Number {
			return _height;
		}
		override public function set height(__value:Number): void {
			throw new Error ("Warning: you cannot set the height of a TextSprite instance.");
		}

		// Textfield extensions
		public function get antiAliasType(): String {
			return textField.antiAliasType;
		}
		public function set antiAliasType(__value:String): void {
			textField.antiAliasType = __value;
		}

		public function get border(): Boolean {
			return textField.border;
		}
		public function set border(__value:Boolean): void {
			textField.border = __value;
		}

		public function get sharpness(): Number {
			return textField.sharpness;
		}
		public function set sharpness(__value:Number): void {
			textField.sharpness = __value;
		}

		public function get thickness(): Number {
			return textField.thickness;
		}
		public function set thickness(__value:Number): void {
			textField.thickness = __value;
		}

		public function get text(): String {
			return textField.text;
		}
		public function set text(__value:String): void {
			textField.text = __value;
			resetTextPosition();
		}

		public function get htmlText(): String {
			return textField.htmlText;
		}
		public function set htmlText(__value:String): void {
			textField.htmlText = __value;
			resetTextPosition();
		}

		public function get embedFonts(): Boolean {
			return textField.embedFonts;
		}
		public function set embedFonts(__value:Boolean): void {
			textField.embedFonts = __value;
			resetTextPosition();
		}
		
		public function get styleSheet(): StyleSheet {
			return textField.styleSheet;
		}
		public function set styleSheet(__value:StyleSheet): void {
			textField.styleSheet = __value;
			resetTextPosition();
		}
		
		public function get multiline(): Boolean {
			return textField.wordWrap;
		}
		public function set multiline(__value:Boolean): void {
			textField.wordWrap = textField.multiline = __value;
			resetTextPosition();
		}

		
		// Textfield format extensions
		public function get font(): String {
			return textField.getTextFormat().font;
		}
		public function set font(__value:String): void {
			setTextFormatProperties({font:__value});
		}

		public function get size(): Number {
			return textField.getTextFormat().size == null ? 12 : (textField.getTextFormat().size as Number);
		}
		public function set size(__value:Number): void {
			setTextFormatProperties({size:__value});
		}

		public function get color(): int {
			return Boolean(textField.getTextFormat().color) ? (textField.getTextFormat().color as int) : 0;
		}
		public function set color(__value:int): void {
			setTextFormatProperties({font:__value});
		}

		public function get align(): String {
			return textField.getTextFormat().align;
		}
		public function set align(__value:String): void {
			setTextFormatProperties({align:__value});
		}

		public function get bold(): Boolean {
			return Boolean(textField.getTextFormat().bold);
		}
		public function set bold(__value:Boolean): void {
			setTextFormatProperties({bold:__value});
		}

		public function get kerning(): Boolean {
			return Boolean(textField.getTextFormat().kerning);
		}
		public function set kerning(__value:Boolean): void {
			setTextFormatProperties({kerning:__value});
		}

		public function get letterSpacing(): Number {
			var ls:Number = Number(textField.getTextFormat().letterSpacing);
			return isNaN(ls) ? 0 : ls;
		}
		public function set letterSpacing(__value:Number): void {
			setTextFormatProperties({letterSpacing:__value});
		}

		public function get leading(): Number {
			var ls:Number = Number(textField.getTextFormat().leading);
			return isNaN(ls) ? 0 : ls;
		}
		public function set leading(__value:Number): void {
			setTextFormatProperties({leading:__value});
		}
	}
}