/**
 * zeh.sound.MiniPlayer
 * Quick player for attached interface sounds
 *
 * @author		Zeh Fernando
 * @version		1.0.0
 *
 * 20 jul 06 (1.0.0) - first version
 *    jan 07 (1.1.0) - added setRoot()
 * 18 feb 07 (1.2.0) - added stopAllSounds()
 * 30 apr 07 (1.3.0) - added getVolume()
 */

/*

Usage:

zeh.sound.MiniPlayer.playSound("aaaa");

Sendo que "aaaa" eh o linkage name do som.

*/

class zeh.sound.MiniPlayer {

	private static var _defaultVolume:Number;			// Default volume
	private static var _myRoot:MovieClip;
	private static var _sounds:Array;					// List of sound folley movieclips

	// ================================================================================================================
	// INSTANCE functions ---------------------------------------------------------------------------------------------

	/**
	 * There's no constructor.
	 *
	 * @param		p_xml				XML Object			Object that should be read (strings -> string -> code | br | en...)
	 */
	public function MiniPlayer () {
		trace ("MiniPlayer is an static class and should not be instantiated.")
	}

	// ================================================================================================================
	// STATIC functions -----------------------------------------------------------------------------------------------

	/**
	 * Reads the string list from a XML object
	 *
	 * @param		p_xml				XML Object			Object that should be read (strings -> string -> code | br | en...)
	 * @return							Boolean				TRUE if the list was successfully read, FALSE if otherwise
	 */
	public static function playSound(p_name:String, p_volume:Number, p_doLoop:Boolean): Void {
		// Initialization where needed
		if (_defaultVolume == undefined) _defaultVolume = 100;
		if (_myRoot == undefined) _myRoot = _root;
		if (_sounds == undefined) _sounds = [];

		if (isNaN(p_volume)) p_volume = _defaultVolume;
		var $name:String = "folley_"+p_name;
		var $sm:MovieClip;
		if (_myRoot[$name] != undefined) {
			$sm = _myRoot[$name];
		} else {
			$sm = _myRoot.createEmptyMovieClip($name, _myRoot.getNextHighestDepth());
			_sounds.push ($sm);
		}
		$sm.ss = new Sound($sm);
		$sm.ss.attachSound (p_name);
		$sm.ss.setVolume (p_volume);
		if (p_doLoop) {
			$sm.ss.start(0, 31337);
		} else {
			$sm.ss.start(0, 0);
		}
		
	}

	public static function setVolume(p_vol:Number): Void {
		_defaultVolume = p_vol;
		var $ss:Sound = new Sound(_myRoot);
		$ss.setVolume(p_vol);
	}

	public static function getVolume(): Number {
		var $ss:Sound = new Sound(_myRoot);
		return $ss.getVolume();
	}

	public static function stopSound(p_name:String): Void {
		var $sm:MovieClip = _myRoot["folley_"+p_name];
		$sm.ss.setVolume(0);
		$sm.ss.stop();
	}
	public static function stopAllSounds(): Void {
		var $i:Number;
		for ($i = 0; $i < _sounds.length; $i++) {
			var $sm:MovieClip = _sounds[$i];
			$sm.ss.setVolume(0);
			$sm.ss.stop();
		}
	}

	public static function setRoot(p_root:MovieClip): Void {
		_myRoot = p_root;
	}
}