/**
 * TextScreen
 * A bit like BitmapData, but holds text screens. Used for oldschool text documents (ANSI and ASCII screens).
 *
 * @author		Zeh Fernando
 * @version		1.0.0 - 3/nov/2006 - First version
 */

/*
This class is NOT COMPLETE. Some of the missing features/methods:

* allow higher ansi screens, with more than one bitmapdata instance (limited to 2880 pixels now)
* better scrolling/wrapping
* it NEEDS A B&W CHARMAP for composition where white = on, black = off. it's a charmap with 16x16 characters. I'm using this one: http://hosted.zeh.com.br/misc/charmap_vga_437_9x16.gif

tm.parsePCB(data:String);
tm.parseANS(data:String);
tm.parseTXT(data:String);
tm.exportPCB():String; // compose? assemble? combine?
tm.exportANS():String;
tm.exportTXT():String;
tm.loadPCB(url:String);
tm.loadANS(url:String);
tm.loadTXT(url:String);

tm.parseAnimationPCB(data:String, datarate:Number); // ansimation


Here's the example for a VERY SIMPLE ansi editor using the class (timeline code):

// start example -----------------------------------

import zeh.display.TextScreen;
import flash.display.BitmapData;

var myBmp:BitmapData = BitmapData.loadBitmap("charmap_vga_437_9x16");
var myAns:TextScreen = new TextScreen(myBmp, 80);

myAns.cursorX = 0;
myAns.cursorY = 0;

this.onKeyDown = function() {
	switch (Key.getCode()) {
	case Key.UP:
		myAns.cursorY--;
		break;
	case Key.DOWN:
		myAns.cursorY++;
		break;
	case Key.LEFT:
		myAns.cursorX--;
		break;
	case Key.RIGHT:
		myAns.cursorX++;
		break;
	case Key.ENTER:
		myAns.cursorX = 0;
		myAns.cursorY++;
	case Key.BACKSPACE:
		myAns.cursorX--;
		myAns.write(" ");
		myAns.cursorX--;
		break;
	default:
		myAns.write(String.fromCharCode(Key.getAscii()));
	}
};
Key.addListener (this);

var mmc:MovieClip = myAns.attachToMovieClip(this, 10);
mmc._x = 0;
mmc._y = 0;

// end example -----------------------------------

*/
import flash.display.BitmapData;
import flash.geom.Point;
import flash.geom.Rectangle;

class zeh.display.TextScreen {

	private var _columns:Number;					// Number of columns for this TextScreen document (usually 80 or 160, defaults to 80)
	private var _charTable:BitmapData;				// BitmapData containing the table of characters to be used (16x16 chars)
	private var _bitmapList:Array;					// Array of BitmapData instances

	private var _screenData:Array;					// Sequential list of characters that make up the drawing (numeric)
	private var _width:Number;						// Width in pixels
	private var _charWidth:Number;					// Character width
	private var _charHeight:Number;					// Character height

	private var _cursorX:Number;					// X position of the cursor (0 -> _columns-1)
	private var _cursorY:Number;					// Y position of the cursor (0 -> ...)
	private var _foregroundColor:Number;			// Foreground color (0-15)
	private var _backgroundColor:Number;			// Background color (0-7)

	private var _colorTable:Array;					// Table of colors

	// ================================================================================================================
	// INSTANCE functions ---------------------------------------------------------------------------------------------

	// Constructor

	/**
	 * Creates a new TextScreen instance.
	 *
	 * @param		p_cols			Number			Number of columns for this TextScreen document (usually 80 or 160, defaults to 80)
	 * @param		p_charTable		BitmapData		BitmapData containing the table of characters to be used (16x16 chars)
	 */
	public function TextScreen (p_charTable:BitmapData, p_columns:Number) {
		_columns = 80;
		_charTable = p_charTable;
		_charWidth = _charTable.width / 16;
		_charHeight = _charTable.height / 16;
		_columns = isNaN(p_columns) ? 80 : p_columns < 1 ? 1 : p_columns;
		_width = _charWidth * _columns;

		_colorTable = [0x000000, 0x0000a8, 0x00a800, 0x00a8a8, 0xa80000, 0xa800a8, 0xa85400, 0xd0d0d0, 0x545454, 0x5454fc, 0x54fc54, 0x54fcfc, 0xfc5454, 0xfc54fc, 0xfcfc54, 0xfcfcfc];

		_cursorX = 0;
		_cursorY = 0;
		_foregroundColor = 7;
		_backgroundColor = 0;

		clear();
	}

	public function redraw(): Void {
		var i:Number;
		var currentRow:Number = 0;
		var currentCol:Number = 0;

		putChar(0, 0, 7, 0, 32); // Just in case it's empty so it forces a redraw

		for (i = 0; i < _screenData.length; i++) {
			putChar(currentCol, currentRow, _screenData[i].foregroundColor, _screenData[i].backgroundColor, _screenData[i].character);
			currentCol++;
			if (currentCol >= 80) {
				currentCol = 0;
				currentRow += 1;
			}
		}

		// TODO: crop the last bitmapdata as needed
		
	}

	public function clear(): Void {
		var i:Number;

		for (i = 0; i < _bitmapList.length; i++) {
			_bitmapList[i].dispose();
			delete _bitmapList[i];
		}

		_bitmapList = new Array();
		_screenData = new Array();
		redraw();
	}

	public function write(p_text:String): Void {
		var i:Number;

		for (i = 0; i < p_text.length; i++) {
			writeChar(p_text.charAt(i));
		}

	}

	private function writeChar(p_char:String): Void {
		putChar(_cursorX, _cursorY, _foregroundColor, _backgroundColor, p_char.charCodeAt(0));
		_cursorX++;
		if (_cursorX >= _columns) {
			_cursorX = 0;
			_cursorY++;
		}
	}

	private function putChar(p_x:Number, p_y:Number, p_foregroundColor:Number, p_backgroundColor:Number, p_charCode:Number): Void {
		var pos:Number = (p_y * (_columns)) + p_x;
		var bitmapIndex:Number = Math.floor((p_y * _charHeight) / 2880);
		if (_bitmapList[bitmapIndex] == undefined) _bitmapList[bitmapIndex] = new BitmapData(_width, 2880, false, 0x000000);

		_screenData[pos] = {character:p_charCode, foregroundColor:p_foregroundColor, backgroundColor:p_backgroundColor};

		var destPoint:Point = new Point(p_x * _charWidth, p_y * _charHeight);
		_bitmapList[bitmapIndex].fillRect(new Rectangle(destPoint.x, destPoint.y, _charWidth, _charHeight), _colorTable[p_backgroundColor]);

		var char:BitmapData = new BitmapData(_charWidth, _charHeight, true, 0xff000000 | _colorTable[p_foregroundColor]);
		//char.copyPixels(_charTable, new Rectangle((p_charCode % 16) * _charWidth, Math.floor(p_charCode / 16) * _charHeight, _charWidth, _charHeight), new Point(0, 0));
		char.copyChannel(_charTable, new Rectangle((p_charCode % 16) * _charWidth, Math.floor(p_charCode / 16) * _charHeight, _charWidth, _charHeight), new Point(0, 0), 1, 8);
		_bitmapList[bitmapIndex].copyPixels(char, char.rectangle, destPoint);
	}

	public function attachToMovieClip(p_mc:MovieClip, p_level:Number): MovieClip {
		var mmc:MovieClip = p_mc.createEmptyMovieClip("___TextScreen_ROX0RZ_"+p_level+"__", p_level);
		var seila = mmc.attachBitmap(_bitmapList[0], 10);
		return mmc;
	}

	// ================================================================================================================
	// GETTER/SETTER functions ----------------------------------------------------------------------------------------

	// columns --------------------------------------------------------------------------------------------------------

	public function get columns():Number {
		return _columns;
	}

	public function set columns(p_columns:Number): Void {
		if (isNaN(p_columns)) return;
		if (p_columns < 1) p_columns = 1;
		_columns = p_columns;
		redraw();
	}

	// charTable ------------------------------------------------------------------------------------------------------

	public function get charTable():BitmapData {
		return _charTable;
	}

	public function set charTable(p_charTable:BitmapData): Void {
		_charTable = p_charTable;
		redraw();
	}

	// cursorX/cursorY ------------------------------------------------------------------------------------------------

	public function get cursorX():Number { return _cursorX; }
	public function get cursorY():Number { return _cursorY; }

	public function set cursorX(p_pos:Number): Void { _cursorX = p_pos < 0 ? 0 : p_pos < _columns ? p_pos : _columns-1; }
	public function set cursorY(p_pos:Number): Void { _cursorY = p_pos < 0 ? 0 : p_pos < _columns ? p_pos : _columns-1; }

	// foregroundColor/backgroundColor -------------------------------------------------------------------------------

	public function get foregroundColor():Number { return _foregroundColor; }
	public function get backgroundColor():Number { return _backgroundColor; }

	public function set foregroundColor(p_clr:Number): Void { _foregroundColor = p_clr < 0 ? 0 : p_clr <= 15 ? p_clr : 15; }
	public function set backgroundColor(p_clr:Number): Void { _backgroundColor = p_clr < 0 ? 0 : p_clr <= 7 ? p_clr : 7; }



}